home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
pc
/
LOGIC Apple II 5.25" Library - DOS Part 2
/
DOS027.dsk
/
AUTO DRIVER.int
< prev
next >
Wrap
Text File
|
2012-02-16
|
4KB
|
113 lines
5 GOTO 10000
180 TREND= RND (3)-1:COUNT=0
190 IF TREND>=0 THEN 192:IF X<=1 THEN 193:X=X-1:GOTO 193
191 S= PEEK (-16336)
192 IF TREND=0 THEN 193:IF X>=R THEN 193:X=X+1
193 S= PEEK (-16336):IF L=0 THEN 198
195 COLOR= 0:HLIN P,P+2 AT LINE:HLIN P,P+2 AT LINE+1:GOTO 200
198 COLOR= 0:HLIN P,P+2 AT LINE-1:HLIN P,P+2 AT LINE:HLIN P,P+2 AT LINE+1
199 COLOR= 8:HLIN P,P+2 AT LINE+2:PLOT P+1,LINE+3
200 CALL -912
202 COLOR= 8:HLIN P,P+2 AT LINE+2:PLOT P+1,LINE+3
204 S= PEEK (-16336):VTAB 24:TAB 2:PRINT A$;:TAB X:PRINT B$;
240 Y=PDL (0)
243 IF Y>85 THEN 246:IF P=0 THEN 260
244 P=P-1:COLOR= 0:PLOT P+3,LINE:PLOT P+3,LINE+2:PLOT P+2,LINE+3:PLOT P+2,LINE+1
245 GOTO 250
246 IF Y<170 THEN 260
247 IF P>36 THEN 260
248 COLOR= 0:PLOT P,LINE:PLOT P,LINE+2:P=P+1
249 PLOT P,LINE+1:PLOT P,LINE+3
250 COLOR= 8:Y= PEEK (-16336)
252 VLIN LINE,LINE+3 AT P+1:HLIN P,P+2 AT LINE+2
254 HLIN P,P+2 AT LINE
260 S= SCRN(P,LINE+3)+ SCRN(P+2,LINE+3)
270 IF S>0 THEN 1000
275 L=L+1:IF L<4 THEN 280
278 L=0:LINE=LINE+1:IF LINE>42 THEN 3000
280 T=T+1:IF T>TIME THEN 2000
290 S= PEEK (-16336)- PEEK (-16336)
300 COUNT=COUNT+1:IF COUNT< RND (10) THEN 190
310 IF RND (3)=2 THEN GOSUB 6000
320 GOTO 180
800 POKE -16304,0: POKE -16302,0: POKE 34,0: POKE 50,63
810 X=35-W- RND (10):LINE=1
815 R=40-W:P=X+2
820 TREND=0:GOTO 830
825 TREND= RND (3)-1
830 COUNT=0
840 VTAB LINE:TAB 2:PRINT A$;
845 VTAB LINE:TAB X:PRINT B$;
850 LINE=LINE+1:IF LINE>24 THEN 900
860 X=X+TREND:IF X<1 THEN X=1:IF X>R THEN X=R:COUNT=COUNT+1:IF COUNT< RND (10) THEN 840:GOTO 825
900 COLOR= 8:HLIN P,P+2 AT 0:HLIN P,P+2 AT 2:VLIN 1,3 AT P+1
910 LINE=0:L=1
950 VTAB 24:TAB 2:PRINT A$;:VTAB 24:TAB X:PRINT B$;
960 GOTO 180
1000 IF SCRN(P,LINE+3)#0 THEN 1005:PP=P+2:GOTO 1010
1005 PP=P
1010 IF PP>38 THEN PP=38:IF PP<1 THEN PP=1:FOR N=1 TO 20
1020 COLOR= 15:GOSUB 1140:COLOR= 0:GOSUB 1100
1030 FOR II=I TO 10:X= PEEK (-16336)- PEEK (-16336):NEXT II
1040 COLOR= 0:GOSUB 1140:COLOR= 15:GOSUB 1100
1045 FOR II=1 TO 10:X= PEEK (-16336):NEXT II
1050 NEXT N
1070 HITS=HITS+1
1080 GOTO 800
1100 PLOT PP,LINE+3:PLOT PP+1,LINE+2:PLOT PP+1,LINE+4:PLOT PP-1,LINE+2:PLOT PP-1,LINE+4:RETURN
1140 FOR I=LINE+2 TO LINE+4:HLIN PP-1,PP+1 AT I:NEXT I:RETURN
2000 POKE -16301,0: POKE 34,20:PRINT
2005 POKE 50,255
2010 PRINT "GAME OVER<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>";
2020 TAB 18:PRINT "CRASHES = ";HITS
2040 PRINT "MADE IT TO THE END ";MADEIT;" TIMES"
2100 PRINT "SKILL LEVEL = ";SKILL;
2200 END
3000 POKE -16301,0: POKE 34,20:CALL -936: POKE 50,255
3005 VTAB 21:TAB 10:PRINT "M A D E I T !<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>";
3010 PRINT :FOR I=1 TO 700:NEXT I
3020 MADEIT=MADEIT+1
3025 POKE 50,63
3030 GOTO 800
5999 REM DRAW SCENARY
6000 S= PEEK (-16336):IF X>(39-X-W) THEN 6030
6010 TREE=X+W+ RND (35-X-W)+2:GOTO 6100
6030 TREE=3+ RND (X-6)
6040 S= PEEK (-16336)- PEEK (-16336)
6100 IF RND (7)>4 THEN 6250:COLOR= 4
6105 IF RND (3)>1 THEN 6200
6110 HLIN TREE,TREE+3 AT 47:VLIN 41,46 AT TREE+1
6120 VLIN 41,46 AT TREE+2:VLIN 41,44 AT TREE:VLIN 41,44 AT TREE+3
6150 RETURN
6200 REM DRAW BUSH
6205 COLOR= 12
6210 HLIN TREE,TREE+2 AT 47
6220 VLIN 43,46 AT TREE+1
6230 VLIN 43,45 AT TREE:VLIN 43,45 AT TREE+2
6240 RETURN
6250 REM DRAW FLOWERS
6260 COLOR= 4:VLIN 45,47 AT TREE+1
6262 VLIN 42,46 AT TREE-1
6265 VLIN 45,47 AT TREE-3:VLIN 46,47 AT TREE-2
6270 COLOR= 9:PLOT TREE+1,44
6275 PLOT TREE,43:PLOT TREE,45:PLOT TREE+2,45:PLOT TREE+2,43
6280 COLOR= 1:PLOT TREE-1,41
6290 COLOR= 8:PLOT TREE-3,44
6295 COLOR= 14:PLOT TREE-2,45
6300 RETURN
10000 REM DRIVER
10010 TEXT :CALL -936
10020 VTAB 5:PRINT " TEST YOUR DRIVING SKILL."
10050 VTAB 8:PRINT "THIS IS THE FULL SPEED VERSION."
10060 VTAB 10:PRINT "PADDLE ZERO IS FOR STEERING."
10070 VTAB 13:PRINT "WHAT IS YOUR SKILL LEVEL?"
10080 VTAB 15:INPUT "(1-10) 1=BEGINNER, 10=EXPERT ",SKILL
10100 PRINT "PLEASE TYPE A QUOTE MARK FOR ME."
10110 INPUT "(SHIFT 2) ",Q$
10112 TIME=800
10115 W=17-SKILL
10120 DIM A$(38),B$(W)
10130 FOR I=1 TO 38:A$(I)=Q$:NEXT I
10140 FOR I=1 TO W:B$(I)="@":NEXT I
20000 GOTO 800